Loadstar 6/006.d81/horror writer

Commodore BASIC | 1984-01-01 | 4.8 KB | 151 lines

10000 poke53281,7:poke53280,6
10005 forc=1to49:print:next
10010 print"[144][147]";:fora=1to40:print"*[146]";:next
10012 print"*[146]      [197]nglish horror movie writer     *";
10014 fora=1to40:print"*[146]";:next
10028 rem
10029 rem ***************************
10030 rem *adapted from the science
10031 rem *fiction novel flowchart
10032 rem *from sam j. lundwall's book,
10033 rem *science fiction, an
10034 rem *illustrated history
10035 rem *(c) 1977 - grosset & dunlap
10038 rem ***************************
10039 rem
10040 print:print"[205]any people have wondered who was"
10041 print:print"really responsible for the hundreds of"
10042 print:print"indistinguishable [194] horror movies of"
10043 print:print"the 50's and 60's.  [207]ur contention is"
10044 print:print"that they were produced by a computer."
10050 print:print"   [193]s evidence, we present the [195]-64"
10051 print:print"screenwriter."
10060 el=76
10070 w=38
10080 restore:dimph$(80),br%(80,8):fora=0toel:readn,ph$(n),br%(n,0)
10085 ifbr%(n,0)=0then10100
10090 forb=1tobr%(n,0):readbr%(n,b):nextb
10100 nexta
10110 print"";
10111 print"         press space bar";
10112 poke198,0:wait198,1:getk$
10120 print:print:ph=0
10122 ca=1
10125 print"":forc=1to20:print"                                       ":
10126 next
10127 print""
10130 rem
10140 rem
10150 t$=t$+ph$(ph)
10155 ifca=1thengosub30000:ca=0
10160 rem
10170 ifbr%(ph,0)=0then10215
10180 pi=br%(ph,0)*rnd(1)+1
10190 pj=br%(ph,pi)
10200 ph=pj
10205 iflen(t$)>wthengosub20000
10210 goto10140
10215 gosub20000:ift$<>p1$thenprintt$
10220 t$="":print:print:print"another?";:poke198,0:wait198,1:getk$
10230 ifk$<>"n"thenifk$<>"[206]"then10120
10240 goto63000
10250 remformatof the data statements:
10260 remdata/phrase#/#of possible branches/branches
10270 data0,"the village ",3,2,3,75
10280 data1,"burns up ",2,5,6
10290 data2,"peasants ",2,12,13
10300 data3,"is attacked by ",2,14,15
10310 data4,"is struck by a giant bat and ",5,7,8,9,0,0
10320 data5,"and everybody dies (the end)",0
10330 data6,"and almost everybody dies (the end)",0
10340 data7,"destroyed[160](the end)",0
10350 data8,"saved (the end)",0
10360 data9,"not destroyed but ",4,10,11,0,0
10370 data10,"everyone dies (the end)",0
10380 data11,"almost everyone dies (the end",0
10390 data12,"dig up ",2,16,17
10400 data13,"discover ",2,16,17
10410 data14,"tiny ",4,18,19,20,66
10420 data15,"giant ",4,18,19,20,66
10430 data16,"tiny ",5,21,22,23,24,25
10440 data17,"giant ",5,21,22,23,24,25
10450 data18,"vampire ",5,21,22,23,24,25
10460 data19,"evil ",5,21,22,23,24,25
10470 data20,"[212]ransylvanian ",5,21,22,23,24,25
10480 data21,"bugs ",1,26
10490 data22,"vampires[160]",1,76
10500 data23,"false teeth ",1,26
10510 data24,"werepersons ",1,76
10520 data25,"batty things ",1,26
10530 data26,"which ",6,27,28,29,30,31,32
10540 data27,"want our women ",2,33,35
10550 data28,"are friendly[160](the end)",0
10560 data29,"are friendly but misunderstood ",1,35
10570 data30,"misunderstand us ",1,35
10580 data31,"understand us too well ",1,35
10590 data32,"look upon us only as a source of nourishment ",2,34,35
10600 data33,"take a few and leave (the end)",0
10610 data34,"and drink our blood (the end)",0
10620 data35,"and are[160]",2,36,37
10630 data36,"alive ",1,38
10640 data37,"not alive ",1,38
10650 data38,"and ",2,39,40
10660 data39,"can be killed by ",7,41,42,43,67,68,69,70
10670 data40,"cannot be killed by ",7,44,45,46,71,72,73,74
10680 data41,"a crowd of peasants with torches (the end)",0
10690 data42,"zombies (the end)",0
10700 data43,"a stake through the heart (the end)",0
10710 data44,"a stake through the heart ",6,47,48,49,54,55,56
10720 data45,"zombies ",6,47,48,49,54,55,56
10730 data46,"a crowd of peasants with torches ",6,47,48,49,54,55,56
10740 data47,"but ",3,53,0,0
10750 data48,"so the morticians invent a weapon ",3,50,51,52
10760 data49,"but ",5,57,58,59,0,0
10770 data50,"which fails[160]",4,47,54,55,56
10780 data51,"which kills them (the end)",0
10790 data52,"which turns them into disgusting lumps (the end)",0
10800 data53,"they die from catching a rare blood disease (the end)",0
10810 data54,"so they kill us (the end)",0
10820 data55,"so they put us under their power (the end)",0
10830 data56,"so they eat us (the end)",0
10840 data57,"a sickly little kid convinces them people are [207].[203]. ",3,60,61,62
10850 data58,"a priest talks to them of [199]od ",3,60,61,62
10860 data59,"they fall in love with this beautiful girl ",4,60,61,62,63
10870 data60,"and they die[160](the end)",0
10880 data61,"and they leave (the end)",0
10890 data62,"and they turn into disgusting slugs (the end)",0
10900 data63,"and they get married and live happily forever after (the end)",0
10910 data64,"sinks into a mud hole ",2,5,6
10920 data65,"turns into a pile of ashes ",2,5,6
10930 data66,"intravenous ",5,21,22,23,24,25
10940 data67,"the burghermeister[160](the end)",0
10950 data68,"[209]uasimodo[160](the end)",0
10960 data69,"the young bride (the end)",0
10970 data70,"the dumb foreigner (the end)",0
10980 data71,"the burghermeister ",6,47,48,49,54,55,56
10990 data72,"[209]uasimodo ",6,47,48,49,54,55,56
11000 data73,"the young bride ",6,47,48,49,54,55,56
11010 data74,"the dumb foreigner ",6,47,48,49,54,55,56
11020 data75,"",4,1,4,64,65
11030 data76,"who ",6,27,28,29,30,31,32
20000 p1$=t$
20010 iflen(t$)>wthenp1$=left$(t$,w)
20015 iflen(t$)<=wthenp1$=t$:goto20050
20020 lp=len(p1$)
20025 p2$=mid$(p1$,lp,1)
20030 ifp2$<>"[160]"thenifp2$<>" "thenlp=lp-1:iflp>1then20025
20040 p1$=left$(t$,lp):t$=mid$(t$,lp)
20050 printp1$
20060 iflen(t$)<=wthenreturn
20070 goto20000
30000 rem capitalize
30005 ift$=""thenreturn
30010 l$=left$(t$,1)
30020 ifl$>="a"andl$<="z"thenl$=chr$(asc(l$)+128)
30030 t$=l$+mid$(t$,2):return
60000 rem"a product of q & d programming"
60010 rem"june, 1982"
63000 rem       link back
63005 print"[147]load"chr$(34)"payload"chr$(34)",8":print"run"
63010 poke198,0:poke631,13:poke632,13:poke198,2:end